Arduino: вывести значения аналогового датчика на LED дисплей

Ниже представлен довольно простой способ вывода значений аналогового датчика на LED дисплей. Для примера взят датчик света.

На собранном макете показан вывод значения освещенного датчика:

и того же датчика в затемненном состоянии:

Электронные компоненты, использованные в примере:

Arduino Nano

LED дисплей MAX7219

Датчик света для Arduino

LED дисплей имеет 5 контактов:

• DIN - data in (информационный вход)
• CS - chip select (номер LED дисплея)
• CLK - clock pulse source (источник тактовых импульсов)
• GND - земля
• 5 V - питание

DIN, CS и CLK подключаются к Arduino через контакты 7, 6 и 5, соответственно.

Датчик света имеет 3 контакта:

• GND
• 5V
• Signal

Signal подключается к Arduino на аналоговый контакт 1.

Эта программа считывает данные сенсора 10 раз в секунду и отображает усредненный результат:

#include <LedControl.h>

const int DIN_PIN = 7;
const int CS_PIN = 6;
const int CLK_PIN = 5;

const int SENSOR_PIN = 1;

LedControl display = LedControl(DIN_PIN, CLK_PIN, CS_PIN);

void setup() {
  display.clearDisplay(0);
  display.shutdown(0, false);
  display.setIntensity(0, 10);
}

void displayNumber(int number) {
  display.clearDisplay(0);
  for (int i = 0; i < 8; i++) {
    int digit = number % 10;
    number /= 10;
    display.setDigit(0, i, digit, false);
    if (number == 0) {
      break;
    }
  }
}

void loop() {
  int value = 0;
  for (int i = 0; i < 10; i++) {
    value += analogRead(SENSOR_PIN);
    delay(100);
  }
  value /= 10;

  displayNumber(value);
}